翡翠台有高清吗:帮看一下ASP代码意思！

我也来学习一下。
是上传组件
我想说的是，搂住应上网搜以-下关于RFC1867
以下是我的理解
文件上传使用RFC1867 (http://image.21tx.com/files/20060405/21463.txt)。 最终被W3C在HTML3.2中接受前，是作为一种建议标准。
在页面间传递数据时form的enctype属性采用ENCTYPE="multipart/form-data"。这种编码方案在传送大量数据的时候，比起缺省的"application/x-url-encoded"表单编码方案，显得效率要高得多。URL编码只有很有限的字符集，使用任何超出字符集的字符，必须用'%nn'代替，这里的nn表示相应的2个十六进制数字。例如，即使是普通的空格字符也要用'%20'代替。而RFC1867使用多部分MIME编码，就象通常在e-mail消息中看到的那样，不编码来传送大量数据，而只是在数据周围加上很少的简单但实用的头部。
<SCRIPT RUNAT=SERVER LANGUAGE=VBSCRIPT>

dim upfile_5xSoft_Stream

Class upload_5xSoft

dim Form,File,Version

Private Sub Class_Initialize
'定义变量
dim iStart,iFileNameStart,iFileNameEnd,iEnd,vbEnter,iFormStart,iFormEnd,theFile
dim strDiv,mFormName,mFormValue,mFileName,mFileSize,mFilePath,iDivLen,mStr
Version=""
if Request.TotalBytes<1 then Exit Sub
'代码开始
set Form=CreateObject("Scripting.Dictionary") '创建一个保存数据键和项目对的对象。
set File=CreateObject("Scripting.Dictionary")
set upfile_5xSoft_Stream=CreateObject("Adodb.Stream")
upfile_5xSoft_Stream.mode=3
upfile_5xSoft_Stream.type=1
upfile_5xSoft_Stream.open
upfile_5xSoft_Stream.write Request.BinaryRead(Request.TotalBytes) '读取所由有表单传来的数据

vbEnter=Chr(13)&Chr(10)
'取得每个项目之间的分隔符
'自定义函数inString返回某字符串在另一字符串中第一次出现的位置。
'自定义函数subString返回位于 String 对象中指定位置的子字符串。
iDivLen=inString(1,vbEnter)+1
strDiv=subString(1,iDivLen)
iFormStart=iDivLen
iFormEnd=inString(iformStart,strDiv)-1
'分解项目
while iFormStart < iFormEnd
iStart=inString(iFormStart,"name=""")
iEnd=inString(iStart+6,"""")
mFormName=subString(iStart+6,iEnd-iStart-6)
iFileNameStart=inString(iEnd+1,"filename=""")
if iFileNameStart>0 and iFileNameStart<iFormEnd then
iFileNameEnd=inString(iFileNameStart+10,"""")
mFileName=subString(iFileNameStart+10,iFileNameEnd-iFileNameStart-10)
iStart=inString(iFileNameEnd+1,vbEnter&vbEnter)
iEnd=inString(iStart+4,vbEnter&strDiv)
'如果是文件
if iEnd>iStart then
mFileSize=iEnd-iStart-4
else
mFileSize=0
end if
set theFile=new FileInfo
theFile.FileName=getFileName(mFileName) '取得文件全名
theFile.FilePath=getFilePath(mFileName) '取得文件路径
theFile.FileSize=mFileSize '取得文件大小
theFile.FileStart=iStart+4
theFile.FormName=FormName
file.add mFormName,theFile
else
iStart=inString(iEnd+1,vbEnter&vbEnter)
iEnd=inString(iStart+4,vbEnter&strDiv)
'如果是表单项目
if iEnd>iStart then
mFormValue=subString(iStart+4,iEnd-iStart-4)
else
mFormValue=""
end if
form.Add mFormName,mFormValue
end if

iFormStart=iformEnd+iDivLen
iFormEnd=inString(iformStart,strDiv)-1
wend
'分解结束
End Sub

Private Function subString(theStart,theLen) '返回位于 String 对象中指定位置的子字符串。
dim i,c,stemp
upfile_5xSoft_Stream.Position=theStart-1
stemp=""
for i=1 to theLen
if upfile_5xSoft_Stream.EOS then Exit for
c=ascB(upfile_5xSoft_Stream.Read(1))
If c > 127 Then
if upfile_5xSoft_Stream.EOS then Exit for
stemp=stemp&Chr(AscW(ChrB(AscB(upfile_5xSoft_Stream.Read(1)))&ChrB(c)))
i=i+1
else
stemp=stemp&Chr(c)
End If
Next
subString=stemp
End function

Private Function inString(theStart,varStr) '返回某字符串在另一字符串中第一次出现的位置。
dim i,j,bt,theLen,str
InString=0
Str=toByte(varStr)
theLen=LenB(Str) '返回字符串varStr长度
for i=theStart to upfile_5xSoft_Stream.Size-theLen
if i>upfile_5xSoft_Stream.size then exit Function
upfile_5xSoft_Stream.Position=i-1
if AscB(upfile_5xSoft_Stream.Read(1))=AscB(midB(Str,1)) then
InString=i
for j=2 to theLen
if upfile_5xSoft_Stream.EOS then
inString=0
Exit for
end if
if AscB(upfile_5xSoft_Stream.Read(1))<>AscB(MidB(Str,j,1)) then
InString=0
Exit For
end if
next
if InString<>0 then Exit Function
end if
next
End Function

Private Sub Class_Terminate
'清除变量及对像
form.RemoveAll
file.RemoveAll
set form=nothing
set file=nothing
upfile_5xSoft_Stream.close
set upfile_5xSoft_Stream=nothing
End Sub

'取得文件路径
Private function GetFilePath(FullPath)
If FullPath <> "" Then
GetFilePath = left(FullPath,InStrRev(FullPath, "\"))
Else
GetFilePath = ""
End If
End function

'取得文件全名
Private function GetFileName(FullPath)
If FullPath <> "" Then
GetFileName = mid(FullPath,InStrRev(FullPath, "\")+1)
Else
GetFileName = ""
End If
End function

Private function toByte(Str)
dim i,iCode,c,iLow,iHigh
toByte=""
For i=1 To Len(Str)
c=mid(Str,i,1)
iCode =Asc(c) '返回c的ANSI字符代码
If iCode<0 Then iCode = iCode + 65535
If iCode>255 Then
iLow = Left(Hex(Asc(c)),2) 'iLow=左边2个
iHigh =Right(Hex(Asc(c)),2) 'iHigh=右边2个
toByte = toByte & chrB("&H"&iLow) & chrB("&H"&iHigh)
Else
toByte = toByte & chrB(AscB(c))
End If
Next
End function
End Class

'文件属性类
Class FileInfo
dim FormName,FileName,FilePath,FileSize,FileStart
Private Sub Class_Initialize
FileName = ""
FilePath = ""
FileSize = 0
FileStart= 0
FormName = ""
End Sub

'保存文件方法
Public function SaveAs(FullPath)
dim dr,ErrorChar,i
SaveAs=1
if trim(fullpath)="" or FileSize=0 or FileStart=0 or FileName="" then exit function
if FileStart=0 or right(fullpath,1)="/" then exit function
set dr=CreateObject("Adodb.Stream")
dr.Mode=3
dr.Type=1
dr.Open
upfile_5xSoft_Stream.position=FileStart-1
upfile_5xSoft_Stream.copyto dr,FileSize
dr.SaveToFile FullPath,2
dr.Close
set dr=nothing
SaveAs=0
end function
End Class
</SCRIPT>
参考：http://www.aspcool.com/lanmu/browse1.asp?ID=2623&bbsuser=asp ASP文件上传原理分析及实现实例（1）
可以类似的学习怎么调用
总之我也不是很懂，恰巧以前碰过。这是以前的心得，我的程序可能和搂住的有细微差别。
期待高手详细的解释

这个是一个上传组件,在上传文件中调用比如在upfile.asp可以加上<!--#include file = "upload_5xSoft.inc"-->